스프레드시트 팁과 노하우: RANDARRAY 함수

추천0

페이지 정보

작성자 MESCIUS

작성일 2021-11-29 16:10 조회 1,030회 댓글 0건

본문

관련링크

RANDARRAY 함수는 강력한 새로운 함수로, RAND 및 RANDBETWEEN을 사용할 필요가 없습니다. 어떠한 인수도 없이 사용하면 RANDARRAY는 RAND 함수처럼 작동하고 0~1 사이의 단일 난수를 반환합니다. 하지만 선택적 인수를 지정하면 필요한 모든 최소값 및 최대값과 함께 정수 또는 소수점 값일 수 있는 난수의 배열을 생성할 수 있습니다.

RANDARRAY 함수는 각 계산 주기의 결과를 자동으로 다시 계산하여 새로운 임의 배열을 생성하는 휘발성 함수입니다. 이 함수는 Monte Carlo 스타일 통계 및 스토캐스틱 분석을 위한 임의 샘플 데이터를 생성하는 데 사용할 수 있습니다.

이 블로그에서 Excel 통합 문서의 RANDARRAY에 대한 예제를 확인할 수 있습니다.

RANDARRAY 구문

RANDARRAY([rows],[columns],[min],[max],[integer])
rows	생성할 난수의 행 수입니다. (기본값 1)
columns	생성할 난수의 열 수입니다. (기본값 1)
min	생성할 값의 최소값입니다. (기본값 0)
max	생성할 값의 최대값입니다. (기본값 1)
integer	정수값을 반환하려면 TRUE (기본값 FALSE)
참고 : 이 함수는 휘발성이므로 워크시트가 변경될 때마다 새 난수가 다시 계산됩니다.

이 예에서는 100~500 사이의 임의 정수 값으로 구성된 10개 행 X 15개 열 배열을 생성합니다.

JavaScript 및 NET 스프레드시트 RANDARRAY 함수 팁과 요령

그림 1 예 1

위 예에서 사용되는 실제 수식은 일반적인 방식으로 사용되는 경우 RANDARRAY 함수가 작동하는 방식을 시뮬레이션하기 위해 좀 더 복잡합니다. 일반적으로 RANDARRAY는 작업의 요구 사항을 직접 충족하기 위해 필요한 값의 임의 배열로 범위를 채우기 위해 하드 코딩된 인수를 지정합니다.

RANDARRAY의 모든 인수는 선택적이므로, 이 수식에서는 인수의 입력 셀이 비어 있을 때 올바른 기본값을 제공하여 인수를 생략하면 RANDARRAY 함수가 어떻게 작동하는지 보여 줍니다.

=RANDARRAY(IF(ISBLANK(B13),1,B13),IF(ISBLANK(B14),1,B14),IF(ISBLANK(B15),0,B15),IF(ISBLANK(B16),1,B16),IF(ISBLANK(B17),FALSE,B17))

워크시트에서 인수를 변경 또는 제거하여 여러 조합을 시도해 보고 RANDARRAY가 각 변경에 대해 새로운 임의 데이터를 생성하기 위해 어떻게 작동하는지 살펴볼 수 있습니다.

다음 예에서는 RANDARRAY와 SORTBY를 사용하여 목록을 임의 순서대로 정렬합니다.

JavaScript 및 NET 스프레드시트 RANDARRAY 함수 팁과 요령

그림 2 예 2

표 SampleList에서 이름을 정렬하는 수식은 RANDARRAY를 사용하여 이름을 정렬하기 위해 SORTBY와 함께 사용할 임의의 숫자 목록을 생성합니다.

=SORTBY(SampleList,RANDARRAY(10))

마지막 예에서는 LEN, MID, SEQUENCE, SORTBY, PROPER, CONCAT와 함께 RANDARRAY를 사용하여 구문에 대한 인수를 생성합니다.

JavaScript 및 NET 스프레드시트 RANDARRAY 함수 팁과 요령

그림 3 예 3

anagram이 생성되는 입력 구문은 셀 B4이고 최종 anagram 결과는 셀 E4입니다. 다음은 anagram을 계산하기 위한 여러 가지 중간 단계입니다.

먼저, 구문의 길이는 셀 C4에서 LEN 함수와 *=LEN(B4)* 수식을 사용하여 계산됩니다.
다음으로, 구문의 각 문자는 SEQUENCE와 MID를 사용하여 유출된 범위 B5#에 대한 별도 셀로 구분되어 수식 *=MID(B4, SEQUENCE(C4),1)*을 사용하여 각 문자를 다른 행으로 추출합니다.
다음으로, 수식 *=SORTBY(SEQUENCE(C4),RANDARRAY(C4))*처럼 SEQUENCE 및 RANDARRAY와 함께 SORTBY를 사용하여 유출된 범위 C5#에서 문자에 대해 새로운 순서가 생성됩니다.
다음으로, 구문의 각 문자는 수식 *=SORTBY(B5#, C5#)*처럼 SORTBY를 사용하여 유출된 범위 E5#에서 새로운 임의 순서로 정렬됩니다.
마지막으로, anagram은 수식 *=PROPER(CONCAT(E5#))*에서처럼 CONCAT과 함께 PROPER를 사용하여 셀 E4에서 계산됩니다.

중간 계산을 위해 별도 수식과 셀을 사용하여 이와 같이 구현할 필요는 없습니다. 이러한 구현은 계산이 어떻게 작동하는지 좀 더 쉽게 이해할 수 있도록 하기 위함입니다. 다음과 같이 단일 수식에서 LET 함수를 사용하여 동일한 계산을 수행할 수 있습니다.

=LET(len,LEN(B4),chars,MID(B4,SEQUENCE(len),1),rnd_order,SORTBY(SEQUENCE(len),RANDARRAY(len)),new_chars,SORTBY(chars, rnd_order),PROPER(CONCAT(new_chars)))